在 Excel 中，F(xiàn)requency函數(shù)用于統(tǒng)計(jì)數(shù)值在指定區(qū)域內(nèi)的出現(xiàn)頻率，并以垂直數(shù)組的形式返回統(tǒng)計(jì)結(jié)果。Frequency函數(shù)不是統(tǒng)計(jì)某個(gè)數(shù)值在指定區(qū)間的出現(xiàn)頻率而是統(tǒng)計(jì)指定區(qū)間有多少個(gè)數(shù)字。

Frequency函數(shù)比較典型的應(yīng)用是統(tǒng)計(jì)不同分?jǐn)?shù)段和不同年齡段的人數(shù)，該應(yīng)用比較簡(jiǎn)單，不需要與其它函數(shù)組合。但若要實(shí)現(xiàn)橫向統(tǒng)計(jì)或連續(xù)出現(xiàn)次數(shù)統(tǒng)計(jì)，則需要與 Transpose、Max、Row 函數(shù)組合，例如 Transpose + Frequency + Row 可實(shí)現(xiàn)橫向統(tǒng)計(jì)。

一、Excel Frequency函數(shù)的語法

1、表達(dá)式：FREQUENCY(Data_Array, Bins_Array)

中文表達(dá)式：頻率計(jì)數(shù)(數(shù)值數(shù)組或?qū)��?shù)值單元格的引用, 區(qū)間數(shù)組)

2、說明：

A、如果 Data_Array 中沒有數(shù)值，F(xiàn)requency函數(shù)只返回一個(gè)零數(shù)組。另外，F(xiàn)requency函數(shù)忽略空白和文本。

B、如果 Bins_Array 中無數(shù)值，F(xiàn)requency函數(shù)將返回 Data_Array 中的元素個(gè)數(shù)。

C、Frequency函數(shù)返回的數(shù)組元素比 Bins_Array 的元素多一個(gè)，多出的元素為大于最高間隔數(shù)值的計(jì)數(shù)，具體見下文的實(shí)例。

D、如果要求Frequency函數(shù)返回?cái)?shù)組，必須以數(shù)組形式輸入，即輸入完公式后要按 Ctrl + Shift + 回車。例如要把不同區(qū)間的統(tǒng)計(jì)結(jié)果填充到相鄰單元格，則選中相鄰單元格后，就需要按 Ctrl + Shift + 回車，具體操作見下文的實(shí)例。

二、Excel Frequency函數(shù)的使用方法及實(shí)例

（一）Frequency函數(shù)忽略空白和文本及返回的數(shù)組元素比 Bins_Array 的元素多一個(gè)的實(shí)例

1、雙擊 C2 單元格，把公式 =INDEX(FREQUENCY(A2:A6,B2:B3),2) 復(fù)制到 C2，按 Ctrl + Shift + 回車（Excel 2016 也可以直接按回車），返回 2；按住 Alt，依次按 M 和 V，打開“公式求值”窗口，按回車求值，則 Frequency函數(shù)返回?cái)?shù)組{1;2;0}；操作過程步驟，如圖1所示：

圖1

2、公式 =INDEX(FREQUENCY(A2:A6,B2:B3),2) 說明：

A、A2:A6 為Frequency函數(shù)的引用單元格區(qū)域，該區(qū)域有空單元格和文本，但它們被忽略；B2:B3 為區(qū)間數(shù)組，可分為三個(gè)區(qū)間，第一個(gè)為小于等于 5，第二個(gè)為大于 5 且小于等于 10，第三個(gè)為大于 10。

B、執(zhí)行時(shí)，第一次在 A2:A6 中統(tǒng)計(jì)第一個(gè)區(qū)間（即小于等于 5）的數(shù)值出現(xiàn)頻率，該區(qū)間只有一個(gè) 5，它的出現(xiàn)頻率為 1，因此返回 1；第二次在 A2:A6 中統(tǒng)計(jì)第二個(gè)區(qū)間（即大于 5 且小于等于 10）的數(shù)值出現(xiàn)頻率，該區(qū)間有 8 和 10 兩個(gè)數(shù)，它們的出現(xiàn)頻率各為 1，因此返回 2（返回的結(jié)果是該區(qū)間各數(shù)出現(xiàn)頻率之和）；第三次在 A2:A6 中統(tǒng)計(jì)第三個(gè)區(qū)間（即大于 10）的數(shù)值出現(xiàn)頻率，由于無大于 10 的數(shù)值，因此返回 0。

C、則 FREQUENCY(A2:A6,B2:B3) 最后返回 {1;2;0}，Bins_Array 參數(shù) B2:B3 只有兩個(gè)元素，而返回?cái)?shù)組 {1;2;0} 有三個(gè)元素，最后一個(gè)元素 0 是統(tǒng)計(jì)第三個(gè)區(qū)間（即大于 10）的數(shù)值出現(xiàn)頻率。

D、則公式變?yōu)?=INDEX({1;2;0},2)，最后用Index函數(shù)返回?cái)?shù)組中第二行第一列的數(shù)值，即返回 2。這里之所以要用Index函數(shù)，是因?yàn)閮H用Frequency函數(shù)若不選中相鄰單元格無法返回?cái)?shù)組。

（二）Frequency函數(shù)返回一個(gè)零數(shù)組的實(shí)例

1、雙擊 A8 單元格，把公式 =FREQUENCY(A2:A7,A2:A7) 復(fù)制到 A8，按回車，返回 0；操作過程步驟，如圖2所示：

圖2

2、公式 =FREQUENCY(A2:A7,A2:A7) 說明：

公式的兩個(gè)參數(shù)都為 A2:A7，由于該區(qū)域全為文本，而Frequency函數(shù)忽略文本，因此結(jié)果返回 0。

（三）有重復(fù)數(shù)字與把不同區(qū)間的統(tǒng)計(jì)結(jié)果填充到相鄰單元格的實(shí)例

1、框選 C2:C3，輸入等號(hào) =，然后按 Ctrl + V 把公式 FREQUENCY(A2:A7,B2:B3) 粘貼到 = 后，按 Ctrl + Shift + 回車，則選中單元格都填上相應(yīng)的統(tǒng)計(jì)結(jié)果；操作過程步驟，如圖3所示：

圖3

2、公式說明：

A、C2 中的結(jié)果 3 是 A2:A7 中小于等于 5 的數(shù)值個(gè)數(shù)，該區(qū)間的共有兩個(gè) 5 和一個(gè) 3，加起來恰好是 3 個(gè)數(shù)值，由此可知Frequency函數(shù)統(tǒng)計(jì)的是區(qū)間的數(shù)值個(gè)數(shù)，而不是某個(gè)數(shù)字的個(gè)數(shù)。

B、C3 中的結(jié)果 8 是 A2:A7 中大于 5 且小于等于 10 的數(shù)值個(gè)數(shù)，該區(qū)間有 6、8 和 10，也是 3 個(gè)數(shù)值。

C、由于同時(shí)框選 C2:C3 且同時(shí)填充公式，它們已經(jīng)組成一個(gè)組，不能單獨(dú)修改或刪除，只有同時(shí)選中它們才能修改或刪除。

三、Excel Frequency函數(shù)的應(yīng)用實(shí)例

（一）統(tǒng)計(jì)不同分?jǐn)?shù)段的人數(shù)實(shí)例

1、假如要統(tǒng)計(jì)不及格、60-69、70-79、80-89、90-99 和 100 分的學(xué)生人數(shù)。框選 D2:D7，輸入等號(hào) =，把公式 FREQUENCY(B2:B28,C2:C6-1) 復(fù)制到 = 后，按 Ctrl + Shift + 回車，統(tǒng)計(jì)出不同分?jǐn)?shù)段的學(xué)生人數(shù)；操作過程步驟，如圖4所示：

圖4

2、公式 =FREQUENCY(B2:B28,C2:C6-1) 說明：

A、由于 C2:C6 中都是 60、70，而要統(tǒng)計(jì)不及格、60-69 這樣分?jǐn)?shù)段的人數(shù)，因此要用 C2:C6-1，其實(shí)是用 C2:C6 中的每個(gè)數(shù)值減 1。如果不減 1，可直接在 C2:C6 中填 59、69、79、89、99。

B、D2 中的統(tǒng)計(jì)結(jié)果 0 是不及格的人數(shù)，D3 中的 1 是 60-69 分?jǐn)?shù)段的人數(shù)，D4 中的 8 是 70-79 分?jǐn)?shù)段的人數(shù)，D5 中的 9 是 80-89 分?jǐn)?shù)段的人數(shù)，D6 中的 9 是 90-99 分?jǐn)?shù)段的人數(shù)，D7 中的 0 是 100 分的人數(shù)。

提示：如果不專門統(tǒng)計(jì) 100 分的人數(shù)，而是把 100 分歸到 90 分以上分?jǐn)?shù)段，可以把 C6 中的 100 改為 101。另外，統(tǒng)計(jì)不同年齡段的人數(shù)也是一樣的方法。

（二）Transpose + Frequency + Row 組合實(shí)現(xiàn)橫向統(tǒng)計(jì)實(shí)例

1、假如要統(tǒng)計(jì) 0 到 7 每個(gè)數(shù)字出現(xiàn)的頻率并把統(tǒng)計(jì)結(jié)果橫向顯示。框選 A10:H10，輸入等號(hào) =，把公式 TRANSPOSE(FREQUENCY(A1:F7,ROW(1:8)-1)) 復(fù)制到 = 后，按 Ctrl + Shift + 回車，則統(tǒng)計(jì)出 A1:F7 中 1 到 7 各數(shù)字的出現(xiàn)頻率；操作過程步驟，如圖5所示：

圖5

2、公式 =TRANSPOSE(FREQUENCY(A1:F7,ROW(1:8)-1)) 說明：

A、ROW(1:8)-1 用于以數(shù)組形式返回 0 到 7 的數(shù)字，ROW(1:8) 以數(shù)組形式返回 1 到 8 的數(shù)字，然后再用每個(gè)數(shù)字減 1，最后返回 0 到 7 的數(shù)字。

B、Transpose函數(shù)把Frequency函數(shù)返回結(jié)果由列轉(zhuǎn)為行，如果不用Transpose函數(shù)，盡管同時(shí)選中 A10:H10，但只能統(tǒng)計(jì)出 0 的頻率。

（三）Max + Frequency + Row 組合統(tǒng)計(jì)連續(xù)次數(shù)最多的實(shí)例

1、假如要統(tǒng)計(jì)連續(xù)增長(zhǎng)最多的月份數(shù)。雙擊 C2 單元格，把公式 =MAX(FREQUENCY(ROW(1:12),(B2:B13<>1)*ROW(1:12)))-1 復(fù)制到 C2，按回車，返回 4；操作過程步驟，如圖6所示：

圖6

2、公式 =MAX(FREQUENCY(ROW(1:12),(B2:B13<>1)*ROW(1:12)))-1 說明：

A、ROW(1:12) 以數(shù)組形式返回 1 到 12 的數(shù)字，即 {1;2;3;4;5;6;7;8;9;10;11;12}。

B、B2:B13 以數(shù)組形式返回 B2:B13 中的所有數(shù)字，即 {1;1;0;1;1;1;1;0;0;1;1;1}；則 B2:B13<>1 變?yōu)?{1;1;0;1;1;1;1;0;0;1;1;1}<>1，接著從數(shù)組中取出每個(gè)元素與 1 比較，如果不等于 1 返回 TRUE，否則返回 FALSE，則最后返回 {FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}。

C、則 (B2:B13<>1)*ROW(1:12) 變?yōu)?{FALSE;FALSE;TRUE;FALSE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE}*{1;2;3;4;5;6;7;8;9;10;11;12}，接著把兩個(gè)數(shù)組中對(duì)應(yīng)的元素相乘（相乘時(shí)，TRUE 轉(zhuǎn)為 1、FALSE 轉(zhuǎn)為 0），則最后返回 {0;0;3;0;0;0;0;8;9;0;0;0}，這樣就求得了 Frequency 的區(qū)間，每個(gè)區(qū)間恰好以 B2:B13 中為 0 的數(shù)值為分割點(diǎn)。

D、則公式變?yōu)?=MAX(FREQUENCY({1;2;3;4;5;6;7;8;9;10;11;12},{0;0;3;0;0;0;0;8;9;0;0;0}))-1，進(jìn)一步計(jì)算，在第一個(gè)數(shù)組中統(tǒng)計(jì)大于 0 且小于等于 3 的數(shù)字個(gè)數(shù)、大于 3 且小于等于 8 的數(shù)字個(gè)數(shù)，大于 8 且小于等于 9 的數(shù)字個(gè)數(shù)和大于 9 的數(shù)字個(gè)數(shù)，結(jié)果為 {0;0;3;0;0;0;0;5;1;0;0;0;3}。

E、則公式變?yōu)?=MAX({0;0;3;0;0;0;0;5;1;0;0;0;3})-1，接著用 Max 對(duì)數(shù)組中的元素求最大值，結(jié)果為 5，5-1 等于 4。之所以要減 1，是因?yàn)橛肍requency函數(shù)統(tǒng)計(jì)每個(gè)區(qū)間的數(shù)字個(gè)數(shù)時(shí)，包含了 B2:B13 中為 0 的數(shù)字，例如統(tǒng)計(jì)大于等于 0 且小于 3 的這個(gè)區(qū)間就包含了 3，而 3 是 B4 中的 0 返回的值。

另外，用 Sum + If + Frequency 組合還可以實(shí)現(xiàn)中國(guó)式排名，具體請(qǐng)參考《Rank函數(shù)怎么用的11個(gè)實(shí)例，含與Rank.EQ和Rank.AVG的區(qū)別、并順自動(dòng)排序和排名次及分段排序》一文。